In this tutorial, we will add a 5-Point tracking sensor module to the robot. The software in this tutorial will read data from the 5-Point Tracking sensor module and automatically guide the smart car to move along the black track line in the white ground.
Parts Required
You can buy your kit @Amazon
- 1x Mecanum wheels robotic car chassis (2x left-wheels +2x right-wheels and 4x motor)
- 1 x Arduino Mega2560
- 1 x Wifi Shield
- 2 x Model X motor driver
- 1x 5-Point Tracking sensor module
- 1x Battery box
- 2x 18650 Batteries(3.7V)
Procedure
Following are the steps required to perform this tutorial.
Hardware Assembly
You must complete this tutorial Mars Explorer Mecanum Wheel Robot – How to Assembly [1] before you continue on with this one. In this tutorial, we will add a 5-Point tracking sensor module to the robot.
Circuit Connection
Step 1: Connect 5-point tracking sensor board to Wifi Shield as per following table.
Step 2: Adjust the sensitivity of tracking sensor modules. Turn on and hold the car and adjust the potentiometer on the tracking sensor with cross screwdriver until you get the best sensitivity status: the signal indicate LED light will turn off when sensor is above white ground, and the signal LED will turn on when the sensor is above black track.
Code
#define MID_SPEED 60
#define HIGH_SPEED 80
#define LOW_SPEED 50
#define LONG_DELAY_TIME 70
#define DELAY_TIME 40
#define SHORT_DELAY_TIME 30
#define speedPinR 9 // Front Wheel PWM pin connect Right MODEL-X ENA
#define RightMotorDirPin1 22 //Front Right Motor direction pin 1 to Right MODEL-X IN1 (K1)
#define RightMotorDirPin2 24 //Front Right Motor direction pin 2 to Right MODEL-X IN2 (K1)
#define LeftMotorDirPin1 26 //Front Left Motor direction pin 1 to Right MODEL-X IN3 (K3)
#define LeftMotorDirPin2 28 //Front Left Motor direction pin 2 to Right MODEL-X IN4 (K3)
#define speedPinL 10 // Front Wheel PWM pin connect Right MODEL-X ENB
#define speedPinRB 11 // Rear Wheel PWM pin connect Left MODEL-X ENA
#define RightMotorDirPin1B 5 //Rear Right Motor direction pin 1 to Left MODEL-X IN1 ( K1)
#define RightMotorDirPin2B 6 //Rear Right Motor direction pin 2 to Left MODEL-X IN2 ( K1)
#define LeftMotorDirPin1B 7 //Rear Left Motor direction pin 1 to Left MODEL-X IN3 (K3)
#define LeftMotorDirPin2B 8 //Rear Left Motor direction pin 2 to Left MODEL-X IN4 (K3)
#define speedPinLB 12 // Rear Wheel PWM pin connect Left MODEL-X ENB
#define sensor1 A0 // Left most sensor
#define sensor2 A1 // 2nd Left sensor
#define sensor3 A2 // center sensor
#define sensor4 A3 // 2nd right sensor// Right most sensor
#define sensor5 A4 // Right most sensor
/*motor control*/
void FR_fwd(int speed) //front-right wheel forward turn
{
digitalWrite(RightMotorDirPin1,HIGH);
digitalWrite(RightMotorDirPin2,LOW);
analogWrite(speedPinR,speed);
}
void FR_bck(int speed) // front-right wheel backward turn
{
digitalWrite(RightMotorDirPin1,LOW);
digitalWrite(RightMotorDirPin2,HIGH);
analogWrite(speedPinR,speed);
}
void FL_fwd(int speed) // front-left wheel forward turn
{
digitalWrite(LeftMotorDirPin1,HIGH);
digitalWrite(LeftMotorDirPin2,LOW);
analogWrite(speedPinL,speed);
}
void FL_bck(int speed) // front-left wheel backward turn
{
digitalWrite(LeftMotorDirPin1,LOW);
digitalWrite(LeftMotorDirPin2,HIGH);
analogWrite(speedPinL,speed);
}
void RR_fwd(int speed) //rear-right wheel forward turn
{
digitalWrite(RightMotorDirPin1B, HIGH);
digitalWrite(RightMotorDirPin2B,LOW);
analogWrite(speedPinRB,speed);
}
void RR_bck(int speed) //rear-right wheel backward turn
{
digitalWrite(RightMotorDirPin1B, LOW);
digitalWrite(RightMotorDirPin2B,HIGH);
analogWrite(speedPinRB,speed);
}
void RL_fwd(int speed) //rear-left wheel forward turn
{
digitalWrite(LeftMotorDirPin1B,HIGH);
digitalWrite(LeftMotorDirPin2B,LOW);
analogWrite(speedPinLB,speed);
}
void RL_bck(int speed) //rear-left wheel backward turn
{
digitalWrite(LeftMotorDirPin1B,LOW);
digitalWrite(LeftMotorDirPin2B,HIGH);
analogWrite(speedPinLB,speed);
}
void forward(int speed_left,int speed_right)
{
RL_fwd(speed_left);
RR_fwd(speed_right);
FR_fwd(speed_right);
FL_fwd(speed_left);
}
void reverse(int speed)
{
RL_bck(speed);
RR_bck(speed);
FR_bck(speed);
FL_bck(speed);
}
void right_shift(int speed_fl_fwd,int speed_rl_bck ,int speed_rr_fwd,int speed_fr_bck)
{
FL_fwd(speed_fl_fwd);
RL_bck(speed_rl_bck);
RR_fwd(speed_rr_fwd);
FR_bck(speed_fr_bck);
}
void left_shift(int speed_fl_bck,int speed_rl_fwd ,int speed_rr_bck,int speed_fr_fwd)
{
FL_bck(speed_fl_bck);
RL_fwd(speed_rl_fwd);
RR_bck(speed_rr_bck);
FR_fwd(speed_fr_fwd);
}
void left_turn(int speed)
{
RL_bck(0);
RR_fwd(speed);
FR_fwd(speed);
FL_bck(0);
}
void right(int speed)
{
RL_fwd(speed);
RR_bck(0);
FR_bck(0);
FL_fwd(speed);
}
void left(int speed)
{
RL_fwd(0);
RR_bck(speed);
FR_bck(speed);
FL_fwd(0);
}
void right_back(int speed)
{
RL_bck(speed);
RR_fwd(0);
FR_fwd(0);
FL_bck(speed);
}
void sharpRightTurn(int speed_left,int speed_right)
{
RL_fwd(speed_left);
RR_bck(speed_right);
FR_bck(speed_right);
FL_fwd(speed_left);
}
void sharpLeftTurn(int speed_left,int speed_right){
RL_bck(speed_left);
RR_fwd(speed_right);
FR_fwd(speed_right);
FL_bck(speed_left);
}
void stop_bot() //Stop
{
analogWrite(speedPinLB,0);
analogWrite(speedPinRB,0);
analogWrite(speedPinL,0);
analogWrite(speedPinR,0);
digitalWrite(RightMotorDirPin1B, LOW);
digitalWrite(RightMotorDirPin2B,LOW);
digitalWrite(LeftMotorDirPin1B, LOW);
digitalWrite(LeftMotorDirPin2B,LOW);
digitalWrite(RightMotorDirPin1, LOW);
digitalWrite(RightMotorDirPin2,LOW);
digitalWrite(LeftMotorDirPin1, LOW);
digitalWrite(LeftMotorDirPin2,LOW);
delay(40);
}
//Pins initialize
void init_GPIO()
{
pinMode(RightMotorDirPin1, OUTPUT);
pinMode(RightMotorDirPin2, OUTPUT);
pinMode(speedPinL, OUTPUT);
pinMode(LeftMotorDirPin1, OUTPUT);
pinMode(LeftMotorDirPin2, OUTPUT);
pinMode(speedPinR, OUTPUT);
pinMode(RightMotorDirPin1B, OUTPUT);
pinMode(RightMotorDirPin2B, OUTPUT);
pinMode(speedPinLB, OUTPUT);
pinMode(LeftMotorDirPin1B, OUTPUT);
pinMode(LeftMotorDirPin2B, OUTPUT);
pinMode(speedPinRB, OUTPUT);
pinMode(sensor1, INPUT);
pinMode(sensor2, INPUT);
pinMode(sensor3, INPUT);
pinMode(sensor4, INPUT);
pinMode(sensor5, INPUT);
stop_bot();
}
void setup()
{
init_GPIO();
Serial.begin(9600);
}
void loop(){
tracking();
}
void tracking()
{
String senstr="";
int s0 = !digitalRead(sensor1);
int s1 = !digitalRead(sensor2);
int s2 = !digitalRead(sensor3);
int s3 = !digitalRead(sensor4);
int s4 = !digitalRead(sensor5);
int sensorvalue=32;
sensorvalue +=s0*16+s1*8+s2*4+s3*2+s4;
senstr= String(sensorvalue,BIN);
senstr=senstr.substring(1,6);
Serial.print(senstr);
Serial.print("\t");
if ( senstr=="10000" || senstr=="01000" || senstr=="11000")
{
Serial.println(" Shift Left");
sharpLeftTurn(LOW_SPEED,MID_SPEED);
// left_shift(HIGH_SPEED,HIGH_SPEED,HIGH_SPEED,HIGH_SPEED);
delay(DELAY_TIME);
stop_bot();
}
if ( senstr=="11100" || senstr=="10100" )
{
Serial.println("Slight Shift Left");
forward(0,HIGH_SPEED);
delay(DELAY_TIME);
stop_bot();
}
if ( senstr=="01100" || senstr=="11110" || senstr=="10010" || senstr=="10110" || senstr=="11010")
{
Serial.println("Slight Left");
forward(LOW_SPEED,MID_SPEED);
delay(DELAY_TIME);
}
if (senstr=="01110" || senstr=="01010" || senstr=="00100" || senstr=="10001" || senstr=="10101" || senstr=="10011" || senstr=="11101" || senstr=="10111" || senstr=="11011" || senstr=="11001")
{
Serial.println("Forward");
forward(MID_SPEED,MID_SPEED);
delay(DELAY_TIME);
stop_bot();
}
if ( senstr=="00110" || senstr=="01111" || senstr=="01001" || senstr=="01011" || senstr=="01101")
{
Serial.println("Slit Right");
forward(MID_SPEED,LOW_SPEED);
delay(DELAY_TIME);
stop_bot();
}
if (senstr=="00111" || senstr=="00101" )
{ Serial.println("Slight Shift to Right ");
forward(HIGH_SPEED,0);
delay(DELAY_TIME);
stop_bot();
}
if (senstr=="00001" || senstr=="00010" || senstr=="00011")
{
Serial.println("Shift to Right");
sharpRightTurn(MID_SPEED,LOW_SPEED);
// right_shift(HIGH_SPEED,HIGH_SPEED,HIGH_SPEED,HIGH_SPEED);
delay(DELAY_TIME);
stop_bot();
}
if ( senstr=="00000"){
reverse(MID_SPEED);
delay(DELAY_TIME/2*3);
stop_bot();
}
if ( senstr=="11111")
{
Serial.println("Sharp Right U Turn");
sharpRightTurn(MID_SPEED,MID_SPEED);
delay(DELAY_TIME);
stop_bot();
}
}
